#--------------------------------------------------------------------------
# PRMI_LLO.kat
#
# FINESSE kat file for L1 PRMI PR gain simulations, including 
# apertures applied to the beam-splitter.  Code for simulation results
# summarised in LIGO-T1300954.   
#
# Code includes locking of MICH and PRCL degrees of freedom.
#
# This FINESSE file uses mirror parameters and positions as measured for
# the cold optics used in LLO.  
# Lengths are taken from E1200274.
# 
# No IMC or PMMT, thin PRM.
#
# Mirror specs taken from https://nebula.ligo.caltech.edu/optics/ as of 
# 2013/08/23
# 
# Thermal lens in ITMs modelled as a thin lens in front of the AR surfaces
# ITMs include non-thermal substrate lenses as calculated from measurements 
# reported in the polisher's reports found on the nebula page.
# For investigation into L1 PR gain no thermal lenses are included (inf
# focal length).
#
# Charlotte Bond, Paul Fulda 2013-09-20
#--------------------------------------------------------------------------

%%% FTblock Laser
###########################################################################
# Laser
l L0 1 0 n0
s lmod1 1 n0 n1
mod mod1 $f1 0.22 1 pm n1 n2
s lmod2 1 n2 n3
mod mod2 $f2 0.179 1 pm n3 nin 
# Input beam mode-matched to case with 50km lens in itm substrates (matched 
# to arm cavities) for LLO design case
#gauss gparam L0 n0 1.3498243m 4.3433202 1.3619432m 4.5706208
###########################################################################
%%% FTend Laser


%%% FTblock PR
###########################################################################
# Distance to power recycling mirror
s lin 1 nin nREFL	

# Power recycling mirror PRM-02
m PRM $R_PRM $T_PRM $phi_PRM nREFL nPRMb
attr PRM Rc 11.009

# Distance between PRM and PR2
s lp1 16.6107 nPRMb nPR2a

# PR2 PR2-02
bs1 PR2 243u 8.6u 0 -0.79 nPR2a nPR2b dump nPOP
attr PR2 Rc -4.545

# Distance from PR2 to PR3
s lp2 16.1647 nPR2b nPR3a

# PR3 PR3-03
bs1 PR3 5.3u 17u 0 0.615 nPR3a nPR3b dump dump
attr PR3 Rc 36.027

# Distance from PR3 to BS
s lp3 19.5381 nPR3b nHRBS_PR
###########################################################################
%%% FTend PR


%%% FTblock BS
###########################################################################
# BS beamsplitter BS-02
##------------------------------------------------------------ 
## BS 
##                             ^ 
##                  to IMY     |      
##                             |      ,'-.
##                             |     +    `. 
##                        nYBS |   ,'       :'
##      nPR3b                  |  +i1      +
##         ---------------->    ,:._  i2 ,'
##    from the PRC       nPRBS + \  `-. + nXBS
##                           ,' i3\   ,' --------------->
##                          +      \ +     to IMX
##                        ,'     i4.'
##                       `._      ..
##                          `._ ,' |nSRBS
##                             -   |
##                                 |to the SRC
##                                 |
##                                 v
##------------------------------------------------------------

# BS BS-02
bs1 HRBS 0.5 8.6u $phi_BS 45 nHRBS_PR nHRBS_Y nHRBS_X nHRBS_SR
s sHRBStoARBSX 0.0685 $nsilica nHRBS_X nARBSX_sub
bs2 ARBSX 30u 1.7u $phi_ARBSX 29.1951 nARBSX_sub dump nARBSX_X dump
s sHRBStoARBSSR 0.0684 $nsilica nHRBS_SR nARBSSR_sub
bs2 ARBSSR 30u 1.7u $phi_ARBSSR -29.1951 nARBSSR_sub dump nARBSSR_SR dump
###########################################################################
%%% FTend BS


%%% FTblock SR
###########################################################################
# Distance from BS to SR3
s ls3 19.3661 nARBSSR_SR nSR3a

# SR3 SR3-01
bs1 SR3 5n 19.1n 0 0 nSR3a nSR3b dump dump
attr SR3 Rc 35.97

# Distance from SR3 to SR2
s ls2 15.4435 nSR3b nSR2a

# SR2 SR2-04
bs1 SR2 7.6n 10.8n 0 0 nSR2a nSR2b dump dump
attr SR2 Rc -6.406

# Distance from SR2 to SRMHR
s ls1 15.7566 nSR2b nSRMHRa

# Signal recycling mirror SRM-08
m1 SRMHR $T_SRM $L_SRM $phi_SRM nSRMHRa nSRMHRb
s SRMsub 0.0749 $nsilica nSRMHRb nSRMARa
attr SRMHR Rc -5.667
m2 SRMAR 50n 0 $phi_SRM nSRMARa nSRMARb
###########################################################################
%%% FTend SR


%%% FTblock Yarm
###########################################################################
# Using values from E1200274
s ly1 4.847 nHRBS_Y nCPYar1

# Y arm compensation plate CP-08
m2 CPYar1 48.9u 0.4u 0 nCPYar1 nCPYar1s
s sCPY 0.1 $nsilica nCPYar1s nCPYar2s
m2 CPYar2 30.5u 0.3u 0 nCPYar2s nCPYar2
s sCPYtoITMYar 0.02 nCPYar2 nITMYTLin

# Y arm input mirror ITM-08
# Thermal lens
lens ITMYTL $TL_f nITMYTLin nITMYTLtrans
s ITMYTL_null 0 nITMYTLtrans nITMYconstL_in
# Constant ITMY substrate lens
lens ITMYconstL -82.4k nITMYconstL_in nITMYconstL_trans
s ITMYTL_null2 0 nITMYconstL_trans nITMYar_in
m2 ITMYar 250u 0 0 nITMYar_in nITMYs1
s lITMY 0.2 $nsilica nITMYs1 nITMYs2
m1 ITMY $T_ITMY $L_ITMY $phi_ITMY nITMYs2 nITMY2
attr ITMY Rc -1940.7
###########################################################################
%%% FTend Yarm


%%% FTblock Xarm
###########################################################################
# Now using length taken from E1200616
s lx1 4.829 nARBSX_X nCPXar1

# X arm compensation plate CP-06 (no values for AR reflection so using same as Yarm)
m2 CPXar1 48.9u 4.3u 0 nCPXar1 nCPXar1s
s sCPX 0.1 $nsilica nCPXar1s nCPXar2s
m2 CPXar2 30.5u 4.8u 0 nCPXar2s nCPXar2
s sCPXtoITMXar 0.02 nCPXar2 nITMXTLin

# X arm input mirror ITM-04
# Thermal lens
lens ITMXTL $TL_f nITMXTLin nITMXTLtrans
s ITMXtl_null 0 nITMXTLtrans nITMXconstL_in
# Non-thermal ITM lens
lens ITMXconstL 305k nITMXconstL_in nITMXconstL_trans
s ITMXTL_null2 0 nITMXconstL_trans nITMXar_in
m2 ITMXar 164u 0 0 nITMXar_in nITMXs1
s lITMX1 0.2 $nsilica nITMXs1 nITMXs2
m1 ITMX $T_ITMX $L_ITMX $phi_ITMX nITMXs2 nITMX2

# default Rc from nebula page
attr ITMX Rc -1937.9
# Rcx for best mode-matching between two arms
#attr ITMX Rc -1901.5
###########################################################################
%%% FTend Xarm


%%% FTblock Reflectivities
###########################################################################
const T_SRM 1		# Just power recycling for current investigation
const L_SRM 0
const R_PRM 0.9689845 
const T_PRM 0.031
const T_ITMX 0.0148
const L_ITMX 175u
const T_ITMY 0.0148
const L_ITMY 265u
###########################################################################
%%% FTend Reflectivities


%%% FTblock Constants
###########################################################################
const nsilica 1.44963098985906
const f1 9099471
const f2 45497355
const TL_f inf
###########################################################################
%%% FTend Constants


%%% FTblock Tunings
###########################################################################
# IFO put on dark fringe
const phi_SRM 90

# (for phase 2 version use these tunings below).  IFO will be locked to
# the dark fringe
const phi_ITMX -2.4
const phi_ITMY 2.4

const phi_BS 0
const phi_ARBSX 0
const phi_ARBSSR 0
const phi_ETMX 0
const phi_ETMY 0

# (for phase 2 version use these tunings below)
# Power recycling cavity will be locked
const phi_PRM 92.5
###########################################################################
%%% FTend Tunings

%%% FTblock HOMs
###########################################################################
# Set PRY and PRX to use cavity eigenmodes for mode calculations
cav cavPRX PRM nPRMb ITMX nITMXs2
cav cavPRY PRM nPRMb ITMY nITMYs2
maxtem 4
phase 2

# Beam-splitter apertures for front (HR) and back (AR) surfaces
# Aperture HR side
attr HRBS r_ap 0.185
# Aperture + offset AR side, X
attr ARBSX r_ap 0.185
attr ARBSX x_off 0.0335
# Aperture + offset AR side, SR
attr ARBSSR r_ap 0.185
attr ARBSSR x_off -0.0335
###########################################################################
%%% FTend HOMs

%%% FTblock beamsizes
###########################################################################
# Beam-sizes at BS
/*
bp wxBS x w nHRBS_Y
bp wyBS y w nHRBS_Y
*/
###########################################################################
%%% FTend beamsizes


%%% FTblock errsigs
###########################################################################
# REFL and AS port I-phase
# REFL port I phase tuned for PRCL, AS port I phase tuned for MICH
# Error signals for locks
pd1 REFL9I $f1 160 nREFL
pd1 AS45I $f2 125 nSRMHRa*
noplot REFL9I
noplot AS45I
###########################################################################
%%% FTend errsigs


%%% FTblock locks
###########################################################################
# Locks for MICH and PRCL degrees of freedom
# PRCL lock
set PRCLerr REFL9I re
lock PRCLlock $PRCLerr 10 1u
put* PRM phi $PRCLlock
noplot PRCLlock

# MICH lock
set MICHerr AS45I re
lock MICHlock $MICHerr -10 1u
put* ITMX phi $MICHlock
func negMICHlock=-$MICHlock
put* ITMY phi $negMICHlock
noplot negMICHlock
noplot MICHlock
###########################################################################
%%% FTend locks


%%% FTblock ring_heater
###########################################################################
# Ring heater effect

# ITMX
xaxis ITMX Rcx lin -1945 -1897 100
put ITMX Rcy $x1

/*
# ITMY
x2axis ITMY Rcx lin -1945 -1902 100
put ITMY Rcy $x2
*/
###########################################################################
%%% FTend ring_heater


%%% FTblock PRC_parameters
###########################################################################
# Scan small range of PR3 Rc, causes large change in beam size at the BS
/*
xaxis PR3 Rcx lin 36 36.035 100
put PR3 Rcy $x1
*/
###########################################################################
%%% FTend PRC_parameters


%%% FTblock offcentre
###########################################################################
# Vary point of incidence of beam on BS (offset from the centre of the 
# front face).
/*
variable x0 0
xaxis x0 phi lin -0.03 0.03 100
put* HRBS x_off $x1
put* ARBSX x_off $x1
put* ARBSSR x_off $x1
*/
###########################################################################
%%% FTend offcentre

%%% FTblock detection
###########################################################################
# Detect reflected power, PRC gain, contrast defect
pd PRgain nPRMb*
pd Pxarm nHRBS_Y*
noplot Pxarm
set Px Pxarm re
pd Pyarm nHRBS_X*
noplot Pyarm
set Py Pyarm re
pd Pout nSRMHRa*
noplot Pout
set Pas Pout re
func CD = $Pas/($Px +$Py + 0.000000001)
pd Prefl nREFL
yaxis lin abs
###########################################################################
%%% FTend detection